3D Movement with Actionscript 3

• Start the CopperCube editor and create a new Free 3D scene. Use the scene as it is, usually, there should be a skybox and a cube named 'cubeMesh' in that scene.
• Add a plane using the 'Create a plane' button on the 'Scene editing' tab with he default values.
• Move the plane a bit so that the scene looks similar to this:

The scene for this example.

• Save the scene as 'test.ccb'
• Publish it as Flash file, using either 'Tools -> Test as Flash Application' or 'File -> Publish -> Publish as Flash Application'. A file named test.swf should now be written out, where you saved the test.ccb file.
• You can now close the CopperCube editor and start your preferred Flash development environment, be it Adobe Flash, Flex, FlexDevelop, Haxe or whatever.

package  
{
	import flash.display.*
	import flash.net.URLRequest;
	import flash.events.Event;
	import flash.events.KeyboardEvent;
	
	public class main extends Sprite 
	{
		private var fileToLoad:String = "test.swf"; 
		private var loader:Loader; 
		private var coppercubeSprite:DisplayObject;
		private var simpleAPI:Object;
		
		public function main()
		{  
			// load the coppercube scene from the other swf
			loader = new Loader();    
			addChild(loader);

			loader.load(new URLRequest(fileToLoad)); 
			loader.contentLoaderInfo.addEventListener(Event.INIT, onCoppercubeLoaded); 
		}  

		// called when the coppercube .swf file has been loaded and initialized
		private function onCoppercubeLoaded(e:Event):void 
		{     
			// get access to the simple API object:
			coppercubeSprite = loader.content as DisplayObject;
			simpleAPI = coppercubeSprite['simpleAPI'];
			
			stage.addEventListener(KeyboardEvent.KEY_DOWN, onKeyDown);
		}
		
		public function onKeyDown(event:KeyboardEvent):void
		{
			// when the 'X' key is pressed, move the scene node with name 'cubeMesh' up a bit
			
			if (event.keyCode == 88 && simpleAPI && simpleAPI.isLoaded())
			{
				var cubeMesh:Object = simpleAPI.getSceneNodeByName("cubeMesh");
				var position:Object = simpleAPI.getSceneNodePosition(cubeMesh);
				
				if (position)
				{
					position.y += 1;
					simpleAPI.setSceneNodePosition(cubeMesh, position.x, position.y, position.z);
				}				
			}
		}
	}
}